package ring

import "base:runtime"
import "core:fmt"

@(private)
ODIN_BOUNDS_CHECK :: !ODIN_NO_BOUNDS_CHECK

Ring :: struct($E: typeid) {
	data:            []E,
	_end_index, len: int,
}

Ring_Soa :: struct($E: typeid) {
	data:            #soa[]E,
	_end_index, len: int,
}

destroy_aos :: #force_inline proc(ring: ^Ring($E)) -> runtime.Allocator_Error {
	return delete(ring.data)
}

destroy_soa :: #force_inline proc(ring: ^Ring_Soa($E)) -> runtime.Allocator_Error {
	return delete(ring.data)
}

destroy :: proc {
	destroy_aos,
	destroy_soa,
}

create_aos :: #force_inline proc(
	$E: typeid,
	capacity: int,
	allocator := context.allocator,
) -> (
	ring: Ring(E),
	err: runtime.Allocator_Error,
) #optional_allocator_error {
	ring.data, err = make([]E, capacity, allocator)
	ring._end_index = -1
	return ring, err
}

create_soa :: #force_inline proc(
	$E: typeid,
	capacity: int,
	allocator := context.allocator,
) -> (
	ring: Ring_Soa(E),
	err: runtime.Allocator_Error,
) #optional_allocator_error {
	ring.data, err = make(#soa[]E, capacity, allocator)
	ring._end_index = -1
	return ring, err
}

init_from_slice_aos :: #force_inline proc(ring: ^Ring($E), data: $T/[]E) {
	ring.data = data
	ring.len = 0
	ring._end_index = -1
	return
}

init_from_slice_soa :: #force_inline proc(ring: ^Ring_Soa($E), data: $T/#soa[]E) {
	ring.data = data
	ring.len = 0
	ring._end_index = -1
	return
}

init_from_slice :: proc {
	init_from_slice_aos,
	init_from_slice_soa,
}

// Index in the backing array where the ring starts
_start_index_aos :: #force_inline proc(ring: Ring($E)) -> int {
	if ring.len < len(ring.data) {
		return 0
	} else {
		start_index := ring._end_index + 1
		return 0 if start_index == len(ring.data) else start_index
	}
}

// Index in the backing array where the ring starts
_start_index_soa :: #force_inline proc(ring: Ring_Soa($E)) -> int {
	if ring.len < len(ring.data) {
		return 0
	} else {
		start_index := ring._end_index + 1
		return 0 if start_index == len(ring.data) else start_index
	}
}

advance_aos :: #force_inline proc(ring: ^Ring($E)) {
	// Length
	if ring.len != len(ring.data) do ring.len += 1
	// End index
	if ring._end_index == len(ring.data) - 1 { 	// If we are at the end of the backing array
		ring._end_index = 0 // Overflow end to 0
	} else {
		ring._end_index += 1
	}
}

advance_soa :: #force_inline proc(ring: ^Ring_Soa($E)) {
	// Length
	if ring.len != len(ring.data) do ring.len += 1
	// End index
	if ring._end_index == len(ring.data) - 1 { 	// If we are at the end of the backing array
		ring._end_index = 0 // Overflow end to 0
	} else {
		ring._end_index += 1
	}
}

advance :: proc {
	advance_aos,
	advance_soa,
}

append_aos :: #force_inline proc(ring: ^Ring($E), element: E) {
	advance(ring)
	ring.data[ring._end_index] = element
}

append_soa :: #force_inline proc(ring: ^Ring_Soa($E), element: E) {
	advance(ring)
	ring.data[ring._end_index] = element
}

append :: proc {
	append_aos,
	append_soa,
}

get_aos :: #force_inline proc(ring: Ring($E), index: int) -> ^E {
	when ODIN_BOUNDS_CHECK {
		fmt.assertf(index < ring.len, "Ring index %i out of bounds for length %i", index, ring.len)
	}

	array_index := _start_index_aos(ring) + index
	if array_index < len(ring.data) {
		return &ring.data[array_index]
	} else {
		array_index = array_index - len(ring.data)
		return &ring.data[array_index]
	}
}

// SOA can't return soa pointer to parapoly T.
get_soa :: #force_inline proc(ring: Ring_Soa($E), index: int) -> E {
	when ODIN_BOUNDS_CHECK {
		fmt.assertf(index < ring.len, "Ring index %i out of bounds for length %i", index, ring.len)
	}

	array_index := _start_index_soa(ring) + index
	if array_index < len(ring.data) {
		return ring.data[array_index]
	} else {
		array_index = array_index - len(ring.data)
		return ring.data[array_index]
	}
}

get :: proc {
	get_aos,
	get_soa,
}

get_last_aos :: #force_inline proc(ring: Ring($E)) -> ^E {
	return get(ring, ring.len - 1)
}

get_last_soa :: #force_inline proc(ring: Ring_Soa($E)) -> E {
	return get(ring, ring.len - 1)
}

get_last :: proc {
	get_last_aos,
	get_last_soa,
}

clear_aos :: #force_inline proc "contextless" (ring: ^Ring($E)) {
	ring.len = 0
	ring._end_index = -1
}

clear_soa :: #force_inline proc "contextless" (ring: ^Ring_Soa($E)) {
	ring.len = 0
	ring._end_index = -1
}

clear :: proc {
	clear_aos,
	clear_soa,
}

// ---------------------------------------------------------------------------------------------------------------------
// ----- Tests ------------------------
// ---------------------------------------------------------------------------------------------------------------------
import "core:log"
import "core:testing"

@(test)
test_ring_aos :: proc(t: ^testing.T) {
	ring := create_aos(int, 10)
	defer destroy(&ring)

	for i in 1 ..= 5 {
		append(&ring, i)
		log.debug("Length:", ring.len)
		log.debug("Start index:", _start_index_aos(ring))
		log.debug("End index:", ring._end_index)
		log.debug(ring.data)
	}
	testing.expect_value(t, get(ring, 0)^, 1)
	testing.expect_value(t, get(ring, 4)^, 5)
	testing.expect_value(t, ring.len, 5)
	testing.expect_value(t, ring._end_index, 4)
	testing.expect_value(t, _start_index_aos(ring), 0)

	for i in 6 ..= 15 {
		append(&ring, i)
		log.debug("Length:", ring.len)
		log.debug("Start index:", _start_index_aos(ring))
		log.debug("End index:", ring._end_index)
		log.debug(ring.data)
	}
	testing.expect_value(t, get(ring, 0)^, 6)
	testing.expect_value(t, get(ring, 4)^, 10)
	testing.expect_value(t, get(ring, 9)^, 15)
	testing.expect_value(t, get_last(ring)^, 15)
	testing.expect_value(t, ring.len, 10)
	testing.expect_value(t, ring._end_index, 4)
	testing.expect_value(t, _start_index_aos(ring), 5)

	for i in 15 ..= 25 {
		append(&ring, i)
		log.debug("Length:", ring.len)
		log.debug("Start index:", _start_index_aos(ring))
		log.debug("End index:", ring._end_index)
		log.debug(ring.data)
	}
	testing.expect_value(t, get(ring, 0)^, 16)
	testing.expect_value(t, ring._end_index, 5)
	testing.expect_value(t, get_last(ring)^, 25)

	clear(&ring)
	append(&ring, 1)
	testing.expect_value(t, ring.len, 1)
	testing.expect_value(t, get(ring, 0)^, 1)
}

@(test)
test_ring_soa :: proc(t: ^testing.T) {
	Ints :: struct {
		x, y: int,
	}

	ring := create_soa(Ints, 10)
	defer destroy(&ring)

	for i in 1 ..= 5 {
		append(&ring, Ints{i, i})
		log.debug("Length:", ring.len)
		log.debug("Start index:", _start_index_soa(ring))
		log.debug("End index:", ring._end_index)
		log.debug(ring.data)
	}
	testing.expect_value(t, get(ring, 0), Ints{1, 1})
	testing.expect_value(t, get(ring, 4), Ints{5, 5})
	testing.expect_value(t, ring.len, 5)
	testing.expect_value(t, ring._end_index, 4)
	testing.expect_value(t, _start_index_soa(ring), 0)

	for i in 6 ..= 15 {
		append(&ring, Ints{i, i})
		log.debug("Length:", ring.len)
		log.debug("Start index:", _start_index_soa(ring))
		log.debug("End index:", ring._end_index)
		log.debug(ring.data)
	}
	testing.expect_value(t, get(ring, 0), Ints{6, 6})
	testing.expect_value(t, get(ring, 4), Ints{10, 10})
	testing.expect_value(t, get(ring, 9), Ints{15, 15})
	testing.expect_value(t, get_last(ring), Ints{15, 15})
	testing.expect_value(t, ring.len, 10)
	testing.expect_value(t, ring._end_index, 4)
	testing.expect_value(t, _start_index_soa(ring), 5)

	for i in 15 ..= 25 {
		append(&ring, Ints{i, i})
		log.debug("Length:", ring.len)
		log.debug("Start index:", _start_index_soa(ring))
		log.debug("End index:", ring._end_index)
		log.debug(ring.data)
	}
	testing.expect_value(t, get(ring, 0), Ints{16, 16})
	testing.expect_value(t, ring._end_index, 5)
	testing.expect_value(t, get_last(ring), Ints{25, 25})

	clear(&ring)
	append(&ring, Ints{1, 1})
	testing.expect_value(t, ring.len, 1)
	testing.expect_value(t, get(ring, 0), Ints{1, 1})
}